Generating background points

In this vignette, we will generate some background points (pseudo-absences) using the different algorithms present in the package. The pseudo-absences are generated through the PseudoAbsences component package.

julia

using SpeciesDistributionToolkit
using CairoMakie

Pseudo-absence generation requires occurrences super-imposed on a layer, so we will collect a few occurrences:

julia

records = OccurrencesInterface.__demodata()
landmass = getpolygon(PolygonData(OpenStreetMap, Places); place="Idaho")
records = Occurrences(mask(records, landmass))
spatial_extent = SpeciesDistributionToolkit.boundingbox(landmass)

(left = -117.24303436279297, right = -111.04356384277344, bottom = 41.988834381103516, top = 49.0008430480957)

We will get a single layer (elevation, but it's not important here):

julia

dataprovider = RasterData(WorldClim2, Elevation)
layer = SDMLayer(dataprovider; resolution=2.5, spatial_extent...)
mask!(layer, landmass)

🗺️  A 170 × 149 layer with 14104 Int16 cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

Pseudo-absences generations always starts by masking a layer by the observations. The output of this command is a layer with Boolean values, where the cells in which at least one occurrence is reported are true.

julia

presencelayer = mask(layer, records)

🗺️  A 170 × 149 layer with 14104 Bool cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

We can for example generate a buffer for pseudo-absences in a radius of 90km around each point. Note that the WithinRadius method uses kilometers and not minutes of arc, so that the actual area is the same regardless of the latitude of the points. Note that the speed of the operation depends on the number of cells with an observation (linearly), and of the radius and raster resolution (to a power of 2). Internally, the code uses a variety of tricks to only look at cells that are susceptible to being pseudo-absences, but the WithinRadius method in particular can take a bit of time.

julia

background = pseudoabsencemask(WithinRadius, presencelayer; distance = 90.0)

🗺️  A 170 × 149 layer with 14104 Bool cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

The pseudo-absence generation functions will return a mask, i.e. a boolean layer where the cells in which we can place a pseudo-absence are true, and the rest of the cells are false. This is useful for a variety of reasons, including adding more and more constraints to the locations of pseudo-absences. For example, we can decide that we do not want background points too close to the actual observations, and put a buffer around each.

julia

buffer = pseudoabsencemask(WithoutRadius, presencelayer; distance = 15.0)

🗺️  A 170 × 149 layer with 14104 Bool cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

We can now exclude the data that are in the buffer:

julia

bgmask = background & buffer

🗺️  A 170 × 149 layer with 14104 Bool cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

Finally, we can plot the area in which we can put pseudo-absences as a shaded region over the layer, and plot all known occurrences as well:

Code for the figure

julia

heatmap(
    layer;
    colormap = :darkterrain,
    axis = (; aspect = DataAspect()),
    figure = (; size = (800, 500)),
)
heatmap!(bgmask; colormap = cgrad([:transparent, :white]; alpha = 0.3))
scatter!(records; color = :black)
hidespines!(current_axis())
hidedecorations!(current_axis())

Note that we can get the same information by using the BetweenRadius method:

julia

pseudoabsencemask(BetweenRadius, presencelayer; closer = 15.0, further = 90.0)

🗺️  A 170 × 149 layer with 14104 Bool cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

There are additional ways to produce pseudo-absences mask, notably the surface range envelope method, which uses the bounding box of observations to allow pseudo-absences:

julia

sre = pseudoabsencemask(SurfaceRangeEnvelope, presencelayer)

🗺️  A 170 × 149 layer with 14104 Bool cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

Code for the figure

julia

heatmap(
    layer;
    colormap = :darkterrain,
    axis = (; aspect = DataAspect()),
    figure = (; size = (800, 500)),
)
heatmap!(sre; colormap = cgrad([:transparent, :white]; alpha = 0.3))
scatter!(records; color = :black)
hidespines!(current_axis())
hidedecorations!(current_axis())

The RandomSelection method (not shown) uses the entire surface of the layer as a possible pseudo-absence location.

Note that we are not yet generating pseudo-absences, and in order to do so, we need to sample the mask generated by pseudoabsencemask. We can do so using backgroundpoints, which uses the StatsBase.sample function internally.

julia

bgpoints = backgroundpoints(bgmask, 2sum(presencelayer))

🗺️  A 170 × 149 layer with 14104 Bool cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

And finally, we can make a plot:

Code for the figure

julia

heatmap(
    layer;
    colormap = :darkterrain,
    axis = (; aspect = DataAspect()),
    figure = (; size = (800, 500)),
)
heatmap!(bgmask; colormap = cgrad([:transparent, :white]; alpha = 0.3))
scatter!(records; color = :black)
scatter!(bgpoints; color = :red, markersize = 4)
hidespines!(current_axis())
hidedecorations!(current_axis())

We can also work with distances in degrees rather than kilometers – for example, this will create a rectangular buffer one degree wide and one degree tall around each observation. Using absolute=true will turn this into a circular buffer:

julia

background = pseudoabsencemask(WithoutDegrees, presencelayer; distance = 0.5, absolute=false)

🗺️  A 170 × 149 layer with 14104 Bool cells
   Projection: +proj=longlat +datum=WGS84 +no_defs

Code for the figure

julia

heatmap(
    layer;
    colormap = :darkterrain,
    axis = (; aspect = DataAspect()),
    figure = (; size = (800, 500)),
)
heatmap!(background; colormap = cgrad([:transparent, :white]; alpha = 0.3))
scatter!(records; color = :black)
hidespines!(current_axis())
hidedecorations!(current_axis())

PseudoAbsences.PseudoAbsenceGenerator Type

julia

PseudoAbsenceGenerator

Abstract type to which all of the pseudo-absences generator types belong. Note that the pseudo-absence types are singleton types, and the arguments are passed when generating the pseudo-absence mask.

Generating background points ​

Related documentation ​

Generating background points

Related documentation